Wenn der Enterprise-Manager nicht verfügbar ist, um einen Aktualisieren des Lagerjobszu erstellen, können Sie dasselbe mit T-SQL-Befehlen erreichen.

Der folgende Jobcode führt eine vollständige Lageraktualisierung durch. Sie können Schritte entfernen, die nicht benötigt werden.

Bearbeiten Sie das Folgende, um es an Ihre Konfiguration anzupassen.

• ServerName - ändern Sie dies in den Servernamen und die Instanz, in der Ihre Datenbank läuft.
• DBname - ändern Sie dies in den Datenbanknamen, in dem Sie den Lagerbestand aktualisieren möchten.

Ersetzen Sie alle Vorkommen von beiden durch Ihre Konfiguration.

begin transaction

declare
  @JobID binary(16),
  @ReturnCode int

set nocount on
select @ReturnCode = 0

-- Jobkopf erstellen
execute @ReturnCode = msdb.dbo.sp_add_job @job_id = @JobID output,
        @job_name = N'Lager aktualisieren - täglich', @enabled = 1,
        @description = N'',
        @category_name = N'[Unkategorisiert (Lokal)]', 
        @notify_level_eventlog = 2, @delete_level= 0
if (@@ERROR <> 0 OR @ReturnCode <> 0)
  goto QuitWithRollback

-- Schritt 1 - Seriennummern aktualisieren
execute @ReturnCode = msdb.dbo.sp_add_jobstep @job_id = @JobID,
        @step_id = 1, @step_name = N'Seriennummern aktualisieren',
        @command = N'exec dl_PA_ObrProm_StetjeSerialNo '''', null, null
          exec dl_PA_ObrProm_StatusSerialNo ''''', @database_name = N'DBname',
        @server = N'', @database_user_name = N'', @subsystem = N'TSQL',
        @cmdexec_success_code = 0, @flags = 0, @retry_attempts = 0,
        @retry_interval = 1, @output_file_name = N'', @on_success_step_id = 0,
        @on_success_action = 3, @on_fail_step_id = 0, @on_fail_action = 2
if (@@ERROR <> 0 OR @ReturnCode <> 0)
  goto QuitWithRollback

-- Schritt 2 - Preise neu berechnen
execute @ReturnCode = msdb.dbo.sp_add_jobstep @job_id = @JobID,
        @step_id = 2, @step_name = N'Preise neu berechnen',
        @command = N'exec dl_PA_ObrProm_CalcCen '''', null, null, ''''
          exec dl_PA_ObrProm_CalcLastCen '''', null, null, ''''
          exec dl_PA_ObrProm_PreracunNabCenZbirno ''''',
        @database_name = N'DBname', @server = N'', 
        @database_user_name = N'',@subsystem = N'TSQL',
        @cmdexec_success_code = 0, @flags = 0, @retry_attempts = 0,
        @retry_interval = 1, @output_file_name = N'', @on_success_step_id = 0,
        @on_success_action = 3, @on_fail_step_id = 0, @on_fail_action = 2
if (@@ERROR <> 0 OR @ReturnCode <> 0)
  goto QuitWithRollback

-- Schritt 3 - Lager aktualisieren
execute @ReturnCode = msdb.dbo.sp_add_jobstep @job_id = @JobID,
        @step_id = 3, @step_name = N'Lager aktualisieren',
        @command = N'exec dl_PA_ObrProm_ObnovitevZaloge ''''',
        @database_name = N'DBname', @server = N'', 
        @database_user_name = N'', @subsystem = N'TSQL',
        @cmdexec_success_code = 0, @flags = 0, @retry_attempts = 0,
        @retry_interval = 1, @output_file_name = N'', @on_success_step_id = 0,
        @on_success_action = 3, @on_fail_step_id = 0, @on_fail_action = 2
if (@@ERROR <> 0 OR @ReturnCode <> 0)
  goto QuitWithRollback

-- Schritt 4 - Dokumentenköpfe aktualisieren
execute @ReturnCode = msdb.dbo.sp_add_jobstep @job_id = @JobID,
        @step_id = 4, @step_name = N'Dokumentenköpfe aktualisieren',
        @command = N'exec dl_PA_ObrProm_PreracunBlagajna null, null
          exec dl_PA_ObrProm_PreracunDenar null, null
          exec dl_PA_ObrProm_PreracunNaroc null, null
          exec dl_PA_ObrProm_PreracunNarocOdprem '''', null, null
          exec dl_PA_ObrProm_PreracunPromet null, null, ''F''',
        @database_name = N'DBname', @server = N'', 
        @database_user_name = N'', @subsystem = N'TSQL',
        @cmdexec_success_code = 0, @flags = 0, @retry_attempts = 0,
        @retry_interval = 1, @output_file_name = N'', @on_success_step_id = 0,
        @on_success_action = 1, @on_fail_step_id = 0, @on_fail_action = 2
if (@@ERROR <> 0 OR @ReturnCode <> 0)
  goto QuitWithRollback

-- Initialen Schritt in den Job schreiben
execute @ReturnCode = msdb.dbo.sp_update_job @job_id = @JobID, @start_step_id = 1
if (@@ERROR <> 0 OR @ReturnCode <> 0)
  goto QuitWithRollback

-- Zeitplan einrichten
execute @ReturnCode = msdb.dbo.sp_add_jobschedule @job_id = @JobID,
        @name = N'Tägliche Ausführung um 01:00', @enabled = 1,
        @freq_type = 4, @active_start_date = 20020103,
        @active_start_time = 10000, @freq_interval = 1,
        @freq_subday_type = 1, @freq_subday_interval = 0,
        @freq_relative_interval = 0, @freq_recurrence_factor = 1,
        @active_end_date = 99991231, @active_end_time = 235959
if (@@ERROR <> 0 OR @ReturnCode <> 0)
  goto QuitWithRollback

-- Job initialisieren
execute @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @JobID,
        @server_name = N'ServerName', @automatic_post = 0
if (@@ERROR <> 0 OR @ReturnCode <> 0)
  goto QuitWithRollback

select @JobID
if (@@ERROR <> 0 OR @ReturnCode <> 0)
  goto QuitWithRollback

commit transaction
goto   EndSave

QuitWithRollback:
  IF (@@TRANCOUNT > 0) rollback transaction
EndSave:

Die gleichen Hinweise gelten für diesen Job wie für den Job, der mit dem Enterprise-Manager erstellt wurde.